-GOTO label 
  .
  .
  .
-label [TYPE text]

where:

label

Is a user-defined name of up to 12 characters. Do not use embedded blanks or the name of any other Dialogue Manager command except -QUIT or -EXIT. Do not use words that may be confused with functions or arithmetic or logical operations.

The label may precede or follow the -GOTO command in the procedure.

TYPE text

Optionally sends a message to a client application.

Dialogue Manager processes a -GOTO as follows:

• It searches forward through the procedure for the target label. If it reaches the end without finding the label, it continues the search from the beginning of the procedure.
• The first time through a procedure, Dialogue Manager notes the addresses of all the labels so that they are found immediately if needed again.
• If a -GOTO does not have a corresponding label, execution halts and a message is displayed.

The following example comments out all the SQL code using an unconditional branch rather than -* in front of every line.

-START TYPE PROCESSING BEGINS
-GOTO DONE
 SQL
 SELECT SUM(UNIT_SOLD),SUM(RETURNS)
 FROM SALES
 WHERE PROD_CODE BETWEEN '&CODE1' AND '&CODE2'
 AND PRODUCT = '&PRODUCT'
GROUP BY PROD_CODE,CITY
-RUN
-DONE

The next example illustrates two labels with TYPE messages appended:

   .
   .
   .
-PRODSALES TYPE TOTAL SALES BY PRODUCT
   .
   .
   .
-PRODRETURNS TYPE TOTAL RETURNS BY PRODUCT

-IF expression [THEN] GOTO label1[;] [ELSE GOTO label2[;]]
                                     [ELSE IF...[;]]

where:

label

Is a user-defined name of up to 12 characters. Do not use embedded blanks or the name of any other Dialogue Manager command except -QUIT or -EXIT. Do not use words that may be confused with functions or arithmetic or logical operations.

The label may precede or follow the -IF command in the procedure.

expression

Is a valid expression. Literals need not be enclosed in single quotation marks unless they contain embedded blanks or commas.

THEN

Is an optional keyword that increases readability of the command.

ELSE GOTO

Optionally passes control to label2 when the -IF test fails.

ELSE IF

Optionally specifies a compound -IF test. See Using Compound -IF Tests.

The command -IF must end with a semicolon (;) to signal that all logic has been specified. Continuation lines must begin with a hyphen (-) and lines must break between words. A space after the hyphen is not required, but adds to readability.

In the following example, control passes to the label -PRODSALES if &OPTION is equal to S. Otherwise, control falls through to the label -PRODRETURNS, the line following the -IF test.

-IF &OPTION EQ 'S' GOTO PRODSALES;
-PRODRETURNS
     SQL
       .
       .
     END
-EXIT
-PRODSALES
     SQL
       .
       .
     END
-EXIT

The following command specifies both transfers explicitly:

-IF &OPTION EQ 'S' GOTO PRODSALES ELSE
- GOTO PRODRETURNS;

Notice that the continuation line begins with a hyphen (-).

Use compound -IF tests provided each test specifies a target label.

In the following example, if the value of &OPTION is neither R nor S, the procedure terminates (GOTO QUIT). The -QUIT serves both as a target label for the GOTO and as an executable command.

-IF &OPTION EQ 'R' THEN GOTO PRODRETURNS ELSE IF
- &OPTION EQ 'S' THEN GOTO PRODSALES ELSE
- GOTO QUIT;
    .
    .
    .
-QUIT

Expressions in a -IF test include arithmetic and logical operators, as well as available functions. See Creating Expressions and Using Functions for details.

To ensure that a supplied value is valid in a procedure, test for its:

• Presence
• Type
• Length

For instance, you would not want to perform a numerical computation on a variable for which alphanumeric data has been supplied.

-IF &name.EXIST GOTO label...;

-IF &OPTION.EXIST GOTO PRODSALES ELSE GOTO CANTRUN;
      .
      .
      .
-PRODSALES
    SQL
      .
      .
      .
    END
-EXIT
-CANTRUN
-TYPE TOTAL REPORT CAN'T BE RUN WITHOUT AN OPTION.
-EXIT

-IF &name.LENGTH expression GOTO label...;

-IF &OPTION.LENGTH GT 1 GOTO FORMAT ELSE
-GOTO PRODSALES;
      .
      .
      .
-PRODSALES
    SQL
      .
      .
      .
    END
-EXIT
-FORMAT
-TYPE ONLY A SINGLE CHARACTER IS ALLOWED.

-PROMPT &WORD.ENTER WORD.
-SET &WORDLEN = &WORD.LENGTH;

-IF &name.TYPE expression GOTO label...;

-IF &OPTION.TYPE NE A GOTO NOALPHA ELSE
- GOTO PRODSALES;
      .
      .
      .
-PRODSALES
    SQL
      .
      .
      .
    END
-EXIT
-NOALPHA
-TYPE ENTER A LETTER ONLY.