-* DESCRIPTION: WebFOCUS Settings required by FORMAT MAGNIFY
-*---------------------------------------------------------------
SET ASNAMES=MIXED
-* DESCRIPTION: Magnify Feed Properties (Required for FORMAT MAGNIFY)
-*---------------------------------------------------------------
ENGINE MAGNIFY SET CONNECTION_ATTRIBUTES MY_PC 'http://localhost:8080/ibi_apps/saxfeed'
ENGINE MAGNIFY SET BASEURL=http://localhost:8080/ibi_apps/WFServlet
ENGINE MAGNIFY SET DATASOURCE=myfileindex
ENGINE MAGNIFY SET MIME=application/openurl
ENGINE MAGNIFY SET BATCHSIZE=10
DEFINE FILE MYFILEINDEXING
-* DESCRIPTION: Parse the File Name to get DOS root
-* Replace DOS root with WEB root
-* Replace DOS slash with WEB slash
-* Create absolute path to file for Magnify to locate and index
-* EXAMINE RESTRICTIONS OF FULL PATH LENGTHS
-*---------------------------------------------------------------
ROOT_DOS_PATH/A15='C:\ibi\apps\';
ROOT_WEB_PATH/A15='/approot/';
DOS_PATH_LEN/I6=ARGLEN(15, ROOT_DOS_PATH, 'I6');
WEB_PATH_LEN/I6=ARGLEN(15, ROOT_WEB_PATH, 'I6');
TEMPWEBPATH/A4000V=STRREP(4000,FILEFNAME,DOS_PATH_LEN,ROOT_DOS_PATH, WEB_PATH_LEN,ROOT_WEB_PATH,4000,'A4000');
FILEWEBPATHRELATIVE/A4000V=STRREP(4000,TEMPWEBPATH,1,'\',1,'/',4000,'A4000');
FILEWEBPATHABSOLUTE/A5000V='http://localhost:8080' || FILEWEBPATHRELATIVE;
-* DESCRIPTION: Collection additional file properties
-*---------------------------------------------------------------
PARENTFOLDER/A4000V=GETTOK(FILEFNAME,4000,-2,'\',1000,'A1000');
FILENAMEEXT/A4000V=GETTOK(FILEFNAME,4000,-1,'\',1000,'A1000');
FILENAME/A4000V=GETTOK(FILENAMEEXT,4000,1,'.',1000,'A1000');
-* DESCRIPTION: Get last action taken on a file
-*---------------------------------------------------------------
MAGNIFYACTION/A25=DECODE FILEMONST( 'DELETED' 'delete'
'MODIFIED' 'add'
'ADDED' 'add'
'RENAMED NEW' 'add'
'RENAMED OLD' 'delete'
'' 'add' ELSE 'add');

-* DESCRIPTION: Create additional fields based on file attributes (File Size, and Format Name)
-*---------------------------------------------------------------
FILESIZERANGE/A50=IF FILESIZE LT 551200 THEN '1. 1 KB - 500 KB'
ELSE IF FILESIZE LT 1102400 THEN '2. 501 KB - 1 MB'
ELSE IF FILESIZE LT 10485760 THEN '3. 1 MB - 10 MB'
ELSE IF FILESIZE LT 104857600 THEN '4. 10 MB - 100 MB'
ELSE IF FILESIZE LT 1073741824 THEN '5. 100 MB - 1 GB'
ELSE '6. 1 GB or higher';
FILEFORMAT/A56=DECODE FILEEXTN( 'ppt' 'MS PowerPoint 97-2003/2010'
'pptx' 'MS PowerPoint 97-2003/2010'
'xls' 'MS Excel 97-2003/2010'
'xlsx' 'MS Excel 97-2003/2010'
'doc' 'MS Word 97-2003/2010'
'docx' 'MS Word 97-2003/2010'
'pdf' 'Portable Document Format'
'odt' 'Open Office Writer'
'mas' 'WebFOCUS Master File'
'sql' 'SQL Queries'
'zip' 'Archive'
'txt' 'Text File'
'jpg' 'Image' ELSE 'Unknown');

-* DESCRIPTION: Create additional fields based on file attributes (File Size, and Format Name)
-*---------------------------------------------------------------
SYSSOURCE/A50='File Repository';
SEARCHTITLE/A2000='<b>File: ' | FILENAME | '(' || FILEEXTN || ')</b><br>DOS Path: ' | FILEFNAME;
SEARCHTITLETMP/A2000='File: ' | FILENAME | '(' || FILEEXTN || ') DOS Path: ' | FILEFNAME;
TITLE_URL/A4000=FILEWEBPATHRELATIVE;
MAGNIFY_ACTUAL_MAGNIFY_DATE/A25='datetime';
MAGNIFY_USAGE_MAGNIFY_DATE/A25='dd/MM/yyyy';
MAGNIFY_ACTION_FILE_PROPERTY_FIELD/A255V='Subject,Author,Category,Keywords';
MAGNIFY_ACTION_FILE_PROPERTY_TITLE/A255V='Subject,Author,Category,Key Terms';
MAGNIFY_ACTION_FILE_PROPERTY_BODY/A255V='Title,Subject,Author,Category,Keywords';
MAGNIFY_ACTION_FILE_BODY/A5000=SYSSOURCE | ' ' | FILEFNAME | ' ' | FILEEXT | ' ' | FILEFORMAT | ' ' | SEARCHTITLETMP;
END

TABLE FILE MYFILEINDEXING
PRINT
FILEWEBPATHABSOLUTE AS 'MagnifyBaseURL'
FILEMONST
MAGNIFYACTION AS 'MagnifyAction'
SEARCHTITLE AS 'SearchTitle'
FILEWEBPATHABSOLUTE AS 'MagnifyID'
FILEWEBPATHABSOLUTE AS 'WF_INDEX_UNIQUE_KEY'
SYSSOURCE AS 'C1_Source_System'
PARENTFOLDER AS 'C2_Parent_Directory'
FILEFORMAT AS 'C3_File_Format'
FILESIZERANGE AS 'C4_File_Size_Ranges'
TITLE_URL
FILEDATE AS 'MAGNIFY_DATE'
MAGNIFY_ACTUAL_MAGNIFY_DATE
MAGNIFY_USAGE_MAGNIFY_DATE
MAGNIFY_ACTION_FILE_PROPERTY_FIELD
MAGNIFY_ACTION_FILE_PROPERTY_TITLE
MAGNIFY_ACTION_FILE_PROPERTY_BODY
MAGNIFY_ACTION_FILE_BODY
ON TABLE HOLD FORMAT MAGNIFY AS MAGN_ASSETS
END